How to Create the Concussion Rifle Mutator:

---

• Download "ConText" from http://fixedsys.com/context/
• Make a copy of "System/UT2004.ini"   as   "System/UT2004dummy.ini"
• In System/UT2004dummy.ini, delete all "EditPackages=..." except
    EditPackages=XWeapons
  EditPackages=ConcussionRifle   <— [change this for each mutator]
  and save.
• Create batch file System/make.bat
  

    @echo off
    del %1.u
    ucc make -ini=UT2004dummy.ini

  and save.

• Context menu:

  Options → Environment Options → ExecuteKeys tab → Add button
  uc → OK
  Click on F9

  Execute box:
    make.bat

  Start In box:
    C:\UT2004\System

  Parameters box:
    ConcussionRifle   <— [change this for each mutator]
  Click on Capture console output
  and on Scroll console to the last line.

  Context menu:
  View → Console output [opens console output window at foot]
   
  

• Create new folder   /UT2004/ConcussionRifle/
• Create subfolder   classes/
• Create and save the 4 files
    ConcussionRifle.uc
  ConcussionRifleFire.uc
  ConcussionRiflePickup.uc
  MutConcuss.uc
  in this subfolder.

The full source code for these four files is presented here:

//=========================================================================
//  ConcussionRifle.uc
//=========================================================================

class ConcussionRifle extends ShockRifle;

defaultproperties
{
    ItemName="Concussion Rifle"
    FireModeClass(0)=ConcussionRifleFire
    PickupClass=class'ConcussionRiflePickUp'
}

//=========================================================================
//  ConcussionRifleFire.uc
//=========================================================================

class ConcussionRifleFire extends ShockBeamFire;

defaultproperties
{
    Momentum=+1000000.0   // sixteen times further than usual.
    DamageMin=5
    DamageMax=5
}

//=========================================================================
//  ConcussionRiflePickup.uc
//=========================================================================

class ConcussionRiflePickup extends ShockRiflePickup;

defaultproperties
{
    InventoryType=class'ConcussionRifle'
    PickupMessage="You have obtained the Concussion Rifle!"
}

//=========================================================================
//  MutConcuss.uc - replaces shock rifle
//=========================================================================

class MutConcuss extends Mutator;

function bool CheckReplacement ( Actor Other, out byte bSuperRelevant )
// Return true if item should be left alone.
// Return false iff item is a shock rifle (on a base or on the ground)
{
    if (xWeaponBase(Other) != None)
    {
        if (xWeaponBase(Other).WeaponType == class'ShockRifle')
            xWeaponBase(Other).WeaponType = class'ConcussionRifle';
        else
            return true;
    }
    else if (WeaponPickup(Other) != None)
    {
        if (string(Other.Class) == "xWeapons.ShockRiflePickup")
            ReplaceWith( Other, "ConcussionRifle.ConcussionRiflePickup");
        else
            return true;
    }
    else
    {
        return true;
    }
    return false;
}

defaultproperties
{
    Description="Main fire causes little damage but flicks the victim far, 
     far away||Alt fire is a normal shock rifle plasma ball"
    FriendlyName="Concussion Rifle"
}

• Go to /UT2004/System/
• Edit UT2004.ini and add
    EditPackages=ConcussionRifle
  and save.
• Delete any old version of System/ConcussionRifle.u
• In command line mode,
    C:\UT2004\System>ucc make
  OR, using the batch file,
    C:\UT2004\System>make ConcussionRifle
  
• To obtain a concussion rifle during an instant action game, press ~ to make the console appear, then type
  summon concussionrifle.concussionriflepickup
• To make the mutator appear in the list of available mutators, create the file "UT2004/System/ConcussionRifle.int" with this code:

[Public]
Object=(Name=ConcussionRifle.MutConcuss,Class=Class,MetaClass=Engine.Mutator,
Description="Concussion Rifle")
Object=(Name=ConcussionRifle.ConcussionRifle,Class=Class,MetaClass=Engine.Weapon,
Description="Main fire causes little damage but flicks the victim far, far away||
Alt fire is a normal shock rifle plasma ball")

  [Return to Doctor Evil’s UT2004 Page]
  [Return to your previous page]